LMOpChange¶

change of variables in a homogeneous linear Mahler equation¶

Calling sequence:¶

$\operatorname{LMOpChange}(L, c, x, M, b)$

Parameters:¶

  • $L$, polynomial in M with polynomial coefficients in $x$
  • $c$, a substitution of the form $\{x = t^{\beta}, y(x) = t^{\alpha} \times z(t)\}$
  • $x$, a name
  • $M$, the name of the Mahler operator
  • $b$, a radix

Description:¶

  • $\operatorname{LMOpChange}(L, c, x, M, b)$ with $c = \{x = t^{\beta}, y(x) = t^{\alpha} \times z(t)\}$ provides the operator $\tilde L(t, M)$ such that $t^{\gamma}\tilde L(t, M) z(t) = L(x, M) y(x)$ with a suitable $\gamma$ and the minimal degree (wrt $t$) of the coefficients of $\tilde L$ is $0$.
  • It is assumed that:
    • $\beta$ is a positive integer,
    • $\alpha$ is an integer,
    • $y$, $t$ and $z$ are names, as $x$.

References:¶

  • Frédéric Chyzak, Thomas Dreyfus, Philippe Dumas, and Marc Mezzarobba (2018). Computing solutions of linear Mahler equations. Mathematics of Computation 87.314, pp. 2977–3021.

Example:¶

In [1]:
libname := libname, FileTools:-JoinPath(["maple","lib","dcfun.mla"],base=homedir):
In [2]:
 with(dcfun):
Out[2]:

Let us consider the following linear Mahler operator.

In [3]:
 b := 2;
Out[3]:

$$2$$

In [4]:
 L := 1 - M + x^2*M^2 - x^10*M^3 + x^34*M^4;
Out[4]:

$$x^{34} M^{4}-x^{10} M^{3}+x^{2} M^{2}-M +1$$

We look at the characteristic polynomials of the operator.

In [5]:
 CH := LMOpConvexHull(L, x, M, b, 'direction' = 'lower');
Out[5]:

$$[\textbf{module}() \,\textbf{export} \,abscissa,\,ordinate,\,slope,\,intercept,\,charpoly; \, \textbf{end}, \textbf{module}() \,\textbf{export} \,abscissa,\,ordinate,\,slope,\,intercept,\,charpoly; \, \textbf{end}, \textbf{module}() \,\textbf{export} \,abscissa,\,ordinate,\,slope,\,intercept,\,charpoly; \, \textbf{end}, \textbf{module}() \,\textbf{export} \,abscissa,\,ordinate,\,slope,\,intercept,\,charpoly; \, \textbf{end}, \textbf{module}() \,\textbf{export} \,abscissa,\,ordinate,\,slope,\,intercept,\,charpoly; \, \textbf{end}]$$

In [6]:
 [seq(CH[i]:-slope, i = 1..nops(CH))];
Out[6]:

$$[0, 1, 2, 3, \infty]$$

In [7]:
 [seq(CH[i]:-charpoly, i = 1..nops(CH))];
Out[7]:

$$[1-\lambda, -1+\lambda, 1-\lambda, -1+\lambda, 0]$$

The rightmost edge of the lower Newton polygon of $L$ provides us with a slope $+3$ and a characteristic polynomial $-1 + \lambda$. (The last element, with infinite slope, is not taken into account.) This tells us that a possible valuation for Laurent series solutions of the equation $L y = 0$ is $-3$. (Laurent series or more generally Puiseux series correspond to $\lambda = 1$. See LMOpSolve.) We change the operator to force the corresponding valuation to be $0$.

In [8]:
 newL := LMOpChange(L,{x = x, y(x) = x^(-3)*y(x)}, x, M, b);
Out[8]:

$$x^{11}-x^{8} M +x^{4} M^{2}+M^{4}-M^{3}$$

In [9]:
 newCH := LMOpConvexHull(newL, x, M, b, 'direction' = 'lower');
Out[9]:

$$[\textbf{module}() \,\textbf{export} \,abscissa,\,ordinate,\,slope,\,intercept,\,charpoly; \, \textbf{end}, \textbf{module}() \,\textbf{export} \,abscissa,\,ordinate,\,slope,\,intercept,\,charpoly; \, \textbf{end}, \textbf{module}() \,\textbf{export} \,abscissa,\,ordinate,\,slope,\,intercept,\,charpoly; \, \textbf{end}, \textbf{module}() \,\textbf{export} \,abscissa,\,ordinate,\,slope,\,intercept,\,charpoly; \, \textbf{end}, \textbf{module}() \,\textbf{export} \,abscissa,\,ordinate,\,slope,\,intercept,\,charpoly; \, \textbf{end}]$$

In [10]:
 [seq(newCH[i]:-slope, i = 1..nops(newCH))];
Out[10]:

$$[-3, -2, -1, 0, \infty]$$

In [11]:
 [seq(newCH[i]:-charpoly, i = 1..nops(newCH))];
Out[11]:

$$[1-\lambda, -1+\lambda, 1-\lambda, -1+\lambda, 0]$$

As a matter of fact, there is no solution with valuation $-3$, but the change has multiplied the solutions by $x^3$.

In [12]:
 Order := 20;
Out[12]:

$$20$$

In [13]:
 LMOpSolve(L, x, M, b, free = K);
Out[13]:

$$K_{1,1}-K_{1,1} x^{2}-K_{1,1} x^{4}-K_{1,1} x^{8}+2 K_{1,1} x^{10}-K_{1,1} x^{16}+K_{1,1} x^{18}+2 K_{1,1} x^{20}+\mathrm{O}\! \left(x^{21}\right)$$

In [14]:
 LMOpSolve(newL, x, M, b, free = K);
Out[14]:

$$K_{1,1} x^{3}-K_{1,1} x^{5}-K_{1,1} x^{7}-K_{1,1} x^{11}+2 K_{1,1} x^{13}-K_{1,1} x^{19}+\mathrm{O}\! \left(x^{21}\right)$$