LMOpEval¶

apply a linear Mahler operator to an expression¶

Calling sequence:¶

$\operatorname{LMOpEval}(L, f, x, M, b)$

Parameters:¶

  • $L$, polynomial in M with (possibly ramified) rational functions in $x$ as coeffs
  • $f$, a Maple expression of algebraic type (in the sense of Maple)
  • $x$, a name
  • $M$, the name of the Mahler operator
  • $b$, a positive integer

Description:¶

  • $\operatorname{LMOpEval}$ provides the result of the action of the linear operator $L$ on the Maple expression $f$.

Example:¶

In [1]:
libname := libname, FileTools:-JoinPath(["maple","lib","dcfun.mla"],base=homedir):
In [2]:
 with(dcfun):
Out[2]:

A linear Mahler operator generalizes the Mahler operator as a linear differential operator generalizes the differentiation.

In [3]:
 b := 3;
Out[3]:

$$3$$

In [4]:
 f := g(x);
Out[4]:

$$g \! \left(x \right)$$

In [5]:
 LMOpEval(x + (1-x)*M, f, x, M, b);
Out[5]:

$$-g \! \left(x^{3}\right) x +x g \! \left(x \right)+g \! \left(x^{3}\right)$$

It can be applied to an object of type series.

In [6]:
 f := series(1/(1-x), x, 10);
Out[6]:

$$1+x +x^{2}+x^{3}+x^{4}+x^{5}+x^{6}+x^{7}+x^{8}+x^{9}+\mathrm{O}\! \left(x^{10}\right)$$

In [7]:
 LMOpEval(x + (1-x)*M, f, x, M, b);
Out[7]:

$$1+x^{2}+2 x^{3}+x^{5}+2 x^{6}+x^{8}+2 x^{9}+\mathrm{O}\! \left(x^{11}\right)$$

Equally it applies to a rational function.

In [8]:
 f := 1/(1-x);
Out[8]:

$$\frac{1}{1-x}$$

In [9]:
 LMOpEval(x + (1-x)*M, 1/(1-x), x, M, b);
Out[9]:

$$-\frac{x^{3}+x^{2}+1}{x^{3}-1}$$

Here we consider a linear Mahler operator.

In [10]:
 L := (x^6+x^3+1)*M^2+(-x^6-x^5-x^4-x^3)*M+x^5;
Out[10]:

$$\left(x^{6}+x^{3}+1\right) M^{2}+\left(-x^{6}-x^{5}-x^{4}-x^{3}\right) M +x^{5}$$

It annihilates on the following function.

In [11]:
 f := x^(1/2)/(1+x^(1/2));
Out[11]:

$$\frac{\sqrt{x}}{1+\sqrt{x}}$$

It is further factorized into $L = AB$ as follows.

In [12]:
 A := (x^6+x^3+1)*M-x^(9/2)-x^5-x^4;
Out[12]:

$$\left(x^{6}+x^{3}+1\right) M -x^{\frac{9}{2}}-x^{5}-x^{4}$$

In [13]:
 B := M-x*(1+x^(3/2))/(x^(5/2)+x^2+x^(3/2)+x+x^(1/2)+1);
Out[13]:

$$M -\frac{x \left(1+x^{\frac{3}{2}}\right)}{x^{\frac{5}{2}}+x^{2}+x^{\frac{3}{2}}+x +\sqrt{x}+1}$$

We can verify this assertion.

In [14]:
 collect(L - LMOpMul(A, B, x, M, b), M, normal);
Out[14]:

$$0$$

If we define $g = Bf$, we must have $Ag = 0$ since $Lf = 0$.

In [15]:
 g := LMOpEval(B, f, x, M, b);
Out[15]:

$$\frac{2 x^{2}}{\left(x +\sqrt{x}+1\right) \left(1+x^{\frac{3}{2}}\right)}$$

In [16]:
 LMOpEval(A, g, x, M, b);
Out[16]:

$$0$$